public class DataBase{
    public static var WordData:Array = new Array(
"1,abeo,アベオ,立ち去る",
"2,ac,アク,そして（接続詞）",
"3,accipio,アッキピオ,受け取る",
"4,ad,アド,〜の方へ",
"5,ad hoc,アドホック,暫定の、臨時の",
"6,ad libitium,アド リビティウム,即興、アドリブ",
"7,admontio,アドモニティオー,忠告",
"8,adversus,アドウェルサス,反対の、逆の",
"9,aeon,イーオン,永遠",
"10,aera,アエラ,時代"
    );
}

#pragma strict
 
public class Quiz{
 
	var kind:int; // 0:○× 1:４択 2:線つなぎ 3:Order
	var questionType:int;
	var question:String;
	var answerCount:int;	// answerCount
	var answerNo:int; 		// answer list no
    var answerList:Array;   // Word List
    var quizWordList:Array; // 同じ単語が選択されないためのリスト
	var wordList:Array;     // DB
 
 
	function Quiz(){
		wordList = DataBase.WordData;
		question = "";
		quizWordList = new Array();
	    for(var i = 0; i < wordList.length; i++){
	    	quizWordList.push(i);
	    }
	}
 
	function create(){
		answerCount = 0;
	    answerList = new Array();
	    kind = Random.Range(0, ConstData.QUESTION_KIND);
 
		var wordCount:int;
		if(kind == 0){
			wordCount = 2;
			answerNo = 0;
			questionType = Random.Range(0,2);
		}else if(kind == 1){
			wordCount = 4;
			answerNo = Random.Range(0,4);
		}else if(kind == 2){
			wordCount = 4;
			answerNo = 0;
		}else if(kind == 3){
			wordCount = 1; 
			answerNo = 0;
		}
 
		for(var i = 0; i < wordCount; i++){
			var rand:int = Random.Range(0,quizWordList.length);
			SetData(wordList[quizWordList[rand]]);
			quizWordList.splice(rand, 1);
		}
		var data:Word = answerList[answerNo];
		if(kind == 0){
			// select2
			if(questionType == 0){
				rand = Random.Range(0,2);
				if(rand == 0){
				    var batuAnswer:Word = answerList[1];
					question = "ラテン語で " + data.latin +"\n日本語では " + batuAnswer.japanese + "である";
					answerNo = 0;
				}else{
					question = "ラテン語で " + data.latin +"\n日本語では " + data.japanese + "である";
					answerNo = 1;
				}
			}else{
				rand = Random.Range(0,2);
				if(rand == 0){
				    batuAnswer = answerList[1];
				    question = "日本語で " + data.japanese +"\nラテン語では " + batuAnswer.latin + "である";
					answerNo = 0;
				}else{
					question = "日本語で " + data.japanese +"\nラテン語では " + data.latin + "である";
					answerNo = 1;
				}
			}
		}else if(kind == 1){
			// select4
			if(questionType == 0){
				question = "ラテン語で " + data.latin +"\n日本語では？";
			}else{
				question = "日本語で " + data.japanese +"\nラテン語では？";
			}
		}else if(kind == 2){
			// lineConnect
			question = "日本語とラテン語の意味があうように\n線をつなげ";
			var str = "";
			var tmp:Array = new Array();
			// 一桁目の０は消えてしまうので１〜にする
			for(i = 1; i < 5; i++){
				tmp.push(i);
			}
 
			for(i = 0; i < wordCount; i++){
				rand = Random.Range(0,tmp.length);
				str += tmp[rand].ToString();
				tmp.splice(rand, 1);
			}
			answerNo = int.Parse(str);
		}else if(kind == 3){
			// order
			var answer:String = data.latin;
			question = "日本語で " + data.japanese +"\nラテン語では\n";
 
			if(answer.Length > 5){
				rand = Random.Range(4,answer.Length);
				if(rand <= 8){
					answerCount = rand;
				}else{
					answerCount = 8;
				}
			}else{
				answerCount = answer.Length;
			}
			for(i = 0; i < answer.Length; i++){
				if(i < answerCount){
					question += "○";
				}else{
					question += answer.Substring(i, 1);
				}
			}			
		}
	}
 
	function SetData(str:String){
		var splitData:Array = str.Split(","[0]);
		var word:Word = new Word();
		word.no = int.Parse(splitData[0]);
		word.latin = splitData[1];
		word.read = splitData[2];
		word.japanese = splitData[3];	
		answerList.push(word);	
	}
 
}

public class Word{
 
	// DBData
	var no:int;
	var latin:String;
	var read:String; 
	var japanese:String;
	var english:String; // TODO
 
}